@echo off
title Remover Servico Frota Trucks
color 0C

net session >nul 2>&1
if not %errorlevel%==0 (
echo ==========================================
echo   PRECISA SER ADMINISTRADOR
echo ==========================================
echo.
echo Clique com o botao direito neste arquivo e escolha
echo "Executar como administrador".
echo.
pause
exit /b 1
)

set SERVICE_NAME=FrotaTrucks
set BASE_DIR=%~dp0
set BASE_DIR=%BASE_DIR:~0,-1%
set NSSM_EXE=%BASE_DIR%\nssm.exe

echo ==========================================
echo   REMOVER SERVICO FROTA TRUCKS
echo ==========================================
echo.

if not exist "%NSSM_EXE%" (
echo [ERRO] NSSM nao encontrado em:
echo %NSSM_EXE%
pause
exit /b 1
)

sc query "%SERVICE_NAME%" >nul 2>&1
if not %errorlevel%==0 (
echo Servico nao existe.
pause
exit /b 0
)

echo Parando servico...
net stop "%SERVICE_NAME%" >nul 2>&1

echo Removendo servico...
"%NSSM_EXE%" remove "%SERVICE_NAME%" confirm

if errorlevel 1 (
echo [ERRO] Falha ao remover servico.
pause
exit /b 1
)

echo.
echo Servico removido com sucesso.
pause
exit /b 0
